End of Road

Score 36 / 350

Gruescript AdventureBy Crowther and Woods (port by anon)

For instructions, click:

You are standing at the end of a road.

Exits:

You can also see:

Save game as:

Really restart this game?

Display options

font:

font size:

Print room title in scroller:

Always

Landscape only

Never

List objects in scroller

Always

Landscape only

Never

This game was made with gruescript.

game Gruescript Adventure
id test
author Crowther and Woods (port by anon)
version 1
person 2
examine on
assign maxscore 350
assign score 36
assign maxinv 7
status { $room.name } | Score { $score } / { $maxscore }

write taken Taken.
localise taken {$taken}
write dropped Dropped.
localise dropped {$dropped}

colour statusbar_background silver
colour statusbar_text black
colour main_background lightgrey
colour main_text black
colour main_prompt black
colour main_text_old grey
colour main_prompt_old grey
colour instructions_button darkgrey
colour instructions_button_text black
colour room_background silver
colour room_text black
colour room_button grey
colour room_button_text black
colour inventory_background silver
colour inventory_text black
colour inventory_button grey
colour inventory_button_text black
colour inventory_inactive_text black
colour save_background lightgrey
colour save_button darkgrey
colour save_button_text black

#setverb cheat intransitive
#at at_end_of_road

#verb cheat
#carry lantern
#goto in_giant_room

#----------------------------------
# Moving in the dark - you can't.
# Moving into light from dark is allowed.

verb go
!litroom $room
!litroom $room.dir.$direction
has lantern warned
say You fell into a pit and broke every bone in your body.
die

verb go
untag lantern warned
!litroom $room
!litroom $room.dir.$direction
say You are surrounded by darkness. If you proceed you will fall into a pit.
tag lantern warned

#------------------------------

room at_end_of_road You are standing at the end of a road. 
prop name End of Road
tags no_dwarf aboveground haswater stream
east inside_building
west at_hill_in_road
south in_a_valley
north in_forest_1

verb go east
at at_end_of_road
tag inside_building visited
continue

thing building small brick building
loc at_end_of_road
desc It seems to be a well house.
verbs enter
tags quiet

verb enter building
goto inside_building

thing stream small stream
loc at_end_of_road
desc The stream flows out of the building and down a gulley.
verbs drink
tags quiet

rule
taghere stream
bring stream

verb drink stream
prompt drink from stream
say The water tastes strongly of minerals, but it is not unpleasant. It is extremely cold.

#------------------------------------

room inside_building You are inside a building, a well house for a large spring.
prop name Inside Building
west at_end_of_road
tags haswater nodwarf aboveground haslight
dir pipes nowhere

thing notice_board
loc inside_building
desc A notice board - with notices.
verbs read
tags list_last

verb read notice_board
goto info

verb go xyzzy
at inside_building
say Saying the magic word 'xyzzy' you are transported to ...
say
goto in_debris_room

verb go pipes
prompt enter pipes
say Too small. The only exit is to the west.

thing food tasty food
loc inside_building
tags portable mass_noun
desc Sure looks yummy!

setverb eat food
held food

verb eat food
say Delicious!
hide food

thing keys set of keys
loc inside_building
tags portable
desc It's just a normal-looking set of keys.
cverbs count

setverb open_grate keys
carried keys
visible steel_grate
has steel_grate closed

verb open_grate keys
say You unlock and open the steel grate revealing a small chamber below
untag steel_grate closed
open outside_grate down below_the_grate
write steel_grate.opened The grate stands open.

verb count keys
say A dozen or so keys.

thing lantern brass lantern
tags portable off
loc inside_building
desc It is a shiny brass lamp. It is not currently lit.
prop battery 330

setverb switch_on lantern
held lantern
!has lantern lightsource
gt lantern.battery 0

setverb switch_off lantern
has lantern lightsource

verb switch_on lantern
gt lantern.battery 0
tag lantern lightsource
say You switch the lantern on.
write lantern.desc It is a shiny brass lamp, glowing brightly.

verb switch_off lantern
untag lantern lightsource
say You switch the lantern off.
write lantern.desc It is a shiny brass lamp. It is not currently lit.

tagdesc lightsource on

rule
!has $room endgame
has lantern lightsource
add lantern.battery -1
eq lantern.battery 0
has lantern lightsource
untag lantern lightsource
write lantern.desc It is a shiny brass lamp. It is not currently lit.
visible lantern
say Your lamp has run out of power.

rule
eq lantern.battery 0
visible lantern
inscope fresh_batteries
hide fresh_batteries
bring wornout_batteries
write lantern.battery 2500
tag lantern lightsource
say I'm taking the liberty of replacing the batteries.

rule
eq lantern.battery 0
visible lantern
!visible fresh_batteries
say You can't explore the cave without a lamp. So Let's just call is a day.
die

rule
eq lantern.battery 30
visible lantern
say Your lamp is getting dim.

rule
eq lantern.battery 30
visible lantern
has lantern batteried
say You're also out of spare batteries.	You'd best start wrapping this up.

rule
at dead_end_14
tag dead_end_14 visited

rule
eq lantern.battery 30
visible lantern
has fresh_batteries in_machine
has dead_end_14 visited
say You'd best start wrapping this up, unless you can find some fresh batteries. I seem to recall there's a vending machine in the maze. Bring some coins with you.

rule
eq lantern.battery 30
visible lantern
!visible fresh_batteries
!has fresh_batteries in_machine
!has lantern batteried
say You'd best go back for those batteries.

thing bottle empty bottle
loc inside_building
desc The bottle is empty.
tags portable

setverb fill bottle
held bottle
taghere hasoil

setverb fill bottle
held bottle
taghere haswater

verb fill bottle
taghere haswater
swap bottle water_bottle
say The bottle is now full of water.

verb fill bottle
taghere hasoil
swap bottle oil_bottle
say The bottle is now full of oil.

thing water_bottle bottle of water
name bottle of water
tags portable
cverbs empty drink

thing oil_bottle bottle of oil
name bottle of oil
tags portable
cverbs empty drink

verb empty
say The bottle is now empty and the ground is now wet.
swap $this bottle

verb drink water_bottle
say The water tastes strongly of minerals, but it is not unpleasant. It is extremely cold.
swap bottle water_bottle

verb drink oil_bottle
say Absolutely not.

#---------------------------------

setverb oil_door oil_bottle
visible rusty_door
!has rusty_door oiled

verb oil_door oil_bottle
swap oil_bottle bottle
tag rusty_door oiled
say The oil has freed up the hinges so that the door will now move, although it requires some effort.

setverb water_plant water_bottle
at in_west_pit

verb water_plant water_bottle
visible tiny_plant
say The plant spurts into furious growth for a few seconds.
swap tiny_plant tall_plant
swap water_bottle bottle
put large_plant_sticking_up at_west_end_of_twopit_room

verb water_plant water_bottle
visible tall_plant
say The plant grows explosively, almost filling the bottom of the pit.
swap tall_plant huge_plant
swap water_bottle bottle

verb water_plant water_bottle
visble huge_plant
say You've over-watered the plant! It's shriveling up! It's, it's...
swap huge_plant tiny_plant
swap water_bottle bottle
hide large_plant_sticking_up at_west_end_of_twopit_room

# -----------------------------------

room at_hill_in_road You have walked up a hill.
prop name Hill in Road
east at_end_of_road
south in_forest_1
tags nodwarf aboveground

thing building2 small brick building
name small brick building
loc at_hill_in_road
desc It seems to be a well house.

setverb enter building2
has inside_building visited

verb enter building2
prompt enter building
has inside_building visited
say OK
goto inside_building

#------------------------------

room in_forest_1 You are in open forest, with a deep valley to one side.
prop name In the Forest
tags aboveground nodwarf
east in_a_valley
north in_forest_1
west in_forest_1
south in_forest_1

verb go north
at in_forest_1
try forest_move: You wander through the trees.
verb go north
at in_forest_1

verb go west
at in_forest_1
try forest_move: You wander through the trees
verb go west
at in_forest_1

verb go south
at in_forest_1
try forest_move: You wander through the trees
verb go south
at in_forest_1

proc forest_move
chance 1 2
goto in_forest_2

room in_forest_2 You are in open forest near both a valley and a road.
prop name In the Forest
tags aboveground nodwarf

east in_a_valley
west in_a_valley
north at_end_of_road
south in_forest_1

#---------------------------------

room in_a_valley You are in a valley beside a stream.
prop name A Valley
tags nodwarf aboveground haswater stream
north at_end_of_road
south at_slit_in_streambed
east in_forest_1
west in_forest_1

verb examine stream
at in_a_valley
say The stream tumbles along a rocky bed.

#----------------------------------

room at_slit_in_streambed You are at a slit in the streambed.
prop name Slit in Streambed
tags nodwarf aboveground haswater stream
north in_a_valley
south outside_grate
east in_forest_1
west in_forest_1

verb examine stream
at at_slit_in_streambed
say The stream flows through the slit.

#---------------------------------

room outside_grate You are in a 20-foot depression.
prop name Outside Grate
west in_forest_1
east in_forest_1
south in_forest_1
north at_slit_in_streambed
tags nodwarf aboveground

thing steel_grate
desc It looks like an ordinary grate mounted in concrete. { steel_grate.opened }
loc outside_grate
tags closed
prop opened The grate is locked closed.

setverb open steel_grate
carried keys
has steel_grate closed

verb open steel_grate
say You unlock and open the steel grate revealing a small chamber below
untag steel_grate closed
open outside_grate down below_the_grate
write steel_grate.opened The grate stands open.

#----------------------------------

room below_the_grate You are in a small chamber.
up outside_grate
west in_cobble_crawl
prop name Below the Grate

thing grate steel grate
name steel grate
loc below_the_grate
desc Above you is the open grate.

#----------------------------------

room in_cobble_crawl You are crawling over cobbles in a low passage.
prop name Cobble Crawl
east below_the_grate
west in_debris_room

thing wicker_cage
desc It's a small wicker cage.
tags portable
loc in_cobble_crawl

#-----------------------------------

room in_debris_room You are in a room filled with debris washed in from the surface.
prop name Debris Room
east in_cobble_crawl
west in_awkward_sloping_e_w_canyon
tags no_dwarf dark

verb go xyzzy
at in_debris_room
say Saying the magic word 'xyzzy' you are transported to ...
say
untag dwarf wandering
hide dwarf
open inside_building xyzzy in_debris_room
goto inside_building

thing note_on_the_wall
loc in_debris_room
desc The note reads "Magic word XYZZY."
verbs read

verb read note_on_the_wall
say "Magic word XYZZY."
open in_debris_room xyzzy inside_building

verb examine note_on_the_wall
open in_debris_room xyzzy inside_building
continue

thing black_rod
desc It's a three foot black rod with a rusty star on an end.
loc in_debris_room
tags portable
cverbs wave

verb wave black_rod
has inside_building caves_closed
say Peculiar. Nothing happens.

verb wave black_rod
!has $room fissure
say Nothing happens

verb wave black_rod
visible bridge
say The crystal bridge has vanished.
hide bridge

verb wave black_rod
say A crystal bridge now spans the fissure.
bring bridge

#------------------------------------

room in_awkward_sloping_e_w_canyon You are in an awkward sloping east/west canyon.
prop name Sloping E/W Canyon
east in_debris_room
west in_bird_chamber
tags no_dwarf dark

#-----------------------------------

room in_bird_chamber You are in a splendid chamber thirty feet high.
prop name Orange River Chamber
east in_awkward_sloping_e_w_canyon
west at_top_of_small_pit
tags no_dwarf dark

thing little_bird
loc in_bird_chamber
desc The cheerful little bird is sitting here singing.
tags alive

setverb catch little_bird
carried wicker_cage

verb catch little_bird
carried black_rod
say The bird was unafraid when you entered, but as you approach it becomes disturbed and you cannot catch it.

verb catch little_bird
say You catch the bird in the wicker cage.
swap wicker_cage caged_bird
hide little_bird

verb examine little_bird
carried black_rod
say The scared little bird is sitting here singing.

setverb catch_bird_in wicker_cage
display catch bird
visible little_bird
held wicker_cage

verb catch_bird_in wicker_cage
carried black_rod
say The bird was unafraid when you entered, but as you approach it becomes disturbed and you cannot catch it.

verb catch_bird_in wicker_cage
say You catch the bird in the wicker cage.
swap wicker_cage caged_bird
hide little_bird

thing caged_bird
tags portable
desc The little bird looks unhappy in the cage.
cverbs release

setverb give caged_bird
display give to snake
visible snake

verb give caged_bird
swap caged_bird wicker_cage
say The snake has now devoured your bird.

verb release caged_bird
visible snake
say The little bird attacks the green snake, and in an astounding flurry drives the snake away.
swap caged_bird wicker_cage
bring little_bird
hide snake
write snake.appearance <cr>

verb release caged_bird
visible dragon
say The little bird attacks the green dragon, and in an astounding flurry gets burnt to a cinder. The ashes blow away.
swap caged_bird wicker_cage

verb release caged_bird
say The little bird flies free.
swap caged_bird wicker_cage
bring little_bird

#------------------------------------

room at_top_of_small_pit You are at the top of a small pit.
prop name Top of Small Pit
tags no_dwarf dark
east in_bird_chamber
down in_hall_of_mists

verb go down
at at_top_of_small_pit
carried gold_nugget
say You are at the bottom of the pit with a broken neck.
die

#-------------------------------------

room in_hall_of_mists You are at one end of a vast hall stretching forward out of sight to the west.
prop name Hall of Mists 
up at_top_of_small_pit
south in_nugget_of_gold_room
west on_east_bank_of_fissure
north in_hall_of_mt_king
tags dark

rule
at in_hall_of_mists
!has in_hall_of_mists scored
add score 25
tag in_hall_of_mists scored

verb go up
at in_hall_of_mists
carried gold_nugget
say The dome is unclimbable.

thing dome
loc in_hall_of_mists
tags passable

setverb climb dome
has dome passable

verb climb dome
say OK
goto at_top_of_small_pit

verb examine dome
has dome passable
say It looks like you might be able to climb it.

verb examine dome
say I'm not sure you'll be able to get up it with what you're carrying.

rule
tag dome passable
carried gold_nugget
untag dome passable

#-----------------------------------

room in_nugget_of_gold_room This is a low room with a crude note on the wall.
north in_hall_of_mists
tags dark
prop name Nugget of Gold Room

thing note
loc in_nugget_of_gold_room
desc "You won't get it up the steps."
tags quiet

thing gold_nugget 
desc It's a large sparkling nugget of gold!
loc in_nugget_of_gold_room
tags portable treasure
prop deposit_take -10
prop deposit_drop 10

#-----------------------------------

room on_east_bank_of_fissure You are on the east bank of a fissure.
prop name East Bank of Fissure
west west_side_of_fissure
east in_hall_of_mists
tags dark fissure
dir jump nowhere

verb go jump
has $room fissure
visible bridge
say I respectfully suggest you go across the bridge instead of jumping.

verb go jump
has $room fissure
say You didn't make it.
die

thing bridge crystal bridge
desc It spans the fissure, thereby providing you a way across.
verbs cross

verb cross bridge
prompt cross crystal bridge
say You walk across the crystal bridge.
say
continue

verb cross bridge
at on_east_bank_of_fissure
goto west_side_of_fissure
bring bridge

verb cross bridge
goto on_east_bank_of_fissure
bring bridge

verb go west
at on_east_bank_of_fissure
!visible bridge
say The fissure is too wide.

verb go west
at on_east_bank_of_fissure
say You walk across the crystal bridge.
say
goto west_side_of_fissure
bring bridge

room west_side_of_fissure You are on the west side of the fissure.
prop name West Side of Fissure
east on_east_bank_of_fissure
tags dark fissure
dir jump nowhere
north at_west_end_of_hall_of_mists

verb go east
at west_side_of_fissure
!visible bridge
say The fissure is too wide.

verb go east
at west_side_of_fissure
say You walk across the crystal bridge.
say
goto on_east_bank_of_fissure
bring bridge

thing diamonds
desc They look to be of the highest quality!
tags portable treasure plural
loc west_side_of_fissure
prop deposit_take -10
prop deposit_drop 10

#-------------------------------------

room at_west_end_of_hall_of_mists You are at the west end of the hall of mists.
prop name West End of Hall of Mists
tags dark
north west_side_of_fissure
west at_east_end_of_long_hall
south alike_maze_1

#------------------------------------

room at_east_end_of_long_hall You are at the east end of a very long hall.
prop name East End of Long Hall
tags dark
east at_west_end_of_hall_of_mists
west at_west_end_of_long_hall
north crossover

#------------------------------------

room at_west_end_of_long_hall You are at the west end of a very long hall.
prop name West End of Long Hall
east at_east_end_of_long_hall
south different_maze_1
north crossover
tags dark

#-----------------------------------

room crossover You are at a crossover of a high N/S passage and a low E/W one.
prop name N/S and E/W Crossover
west at_east_end_of_long_hall
north dead_end_7
east in_west_side_chamber
south at_west_end_of_long_hall
tags dark

#------------------------------------

room dead_end_7 You are at a dead end.
prop name Dead End
south crossover

#-----------------------------------

room in_hall_of_mt_king You are in the hall of the mountain king, with passages off in all directions.
prop name Hall of the Mountain King
up in_hall_of_mists
east in_hall_of_mists
north low_n_s_passage
south in_south_side_chamber
west in_west_side_chamber
southwest in_secret_e_w_canyon

northwest nowhere
southeast nowhere
northeast nowhere
down nowhere

verb go northwest
at in_hall_of_mt_king
run going_nowhere

verb go northeast
at in_hall_of_mt_king
run going_nowhere

verb go southeast
at in_hall_of_mt_king
run going_nowhere

verb go down
at in_hall_of_mt_king
run going_nowhere

proc going_nowhere
say Well, perhaps not quite all directions.
close in_hall_of_mt_king down
close in_hall_of_mt_king northeast
close in_hall_of_mt_king northwest
close in_hall_of_mt_king southeast
write in_hall_of_mt_king.desc You are in the hall of the Mountain King.

verb go north
at in_hall_of_mt_king
visible snake
say You can't get by the snake.

verb go south
at in_hall_of_mt_king
visible snake
say You can't get by the snake.

verb go west
at in_hall_of_mt_king
visible snake
say You can't get by the snake.

verb go southwest
at in_hall_of_mt_king
visible snake
chance 36 100
say You can't get by the snake.

thing snake
loc in_hall_of_mt_king
desc I wouldn't mess with it if I were you.
verbs attack talk take

verb attack snake
say Attacking the snake both doesn't work and is very dangerous.

verb talk snake
display talk to
say Hiss!

verb take snake
say It takes you instead.
die

#-------------------------------------

room low_n_s_passage You are in a low N/S passage at a hole in the floor.
prop name Low N/S Passage
tags dark
south in_hall_of_mt_king
down in_dirty_passage
north at_y2

thing bars_of_silver
loc low_n_s_passage
desc They're probably worth a fortune!
tags treasure plural portable
prop deposit_take -10
prop deposit_drop 10

#-------------------------------------

room in_south_side_chamber You are in the south side chamber.
prop name South Side Chamber
tags dark
north in_hall_of_mt_king

thing precious_jewelry
loc in_south_side_chamber
desc It's all quite exquisite.
tags treasure portable mass_noun
prop deposit_take -10
prop deposit_drop 10

#-------------------------------------

room in_west_side_chamber You are in the west side chamber.
prop name West Side Chamber
tags dark
west crossover
east in_hall_of_mt_king

thing rare_coins
loc in_west_side_chamber
tags treasure portable plural
desc They're a numismatist's dream!
prop deposit_take -10
prop deposit_drop 10

#-------------------------------------

room at_y2 You are at "Y2".	
tags dark
south low_n_s_passage
east jumble_of_rock
west at_window_on_pit_1
prop name Y2

rule
at in_plover_room
open at_y2 plover in_plover_room

verb go plover
at at_y2
carried egg_sized_emerald
put egg_sized_emerald in_plover_room
add score -5
untag dwarf wandering
hide dwarf
continue

thing rock
loc at_y2
desc There is a large "Y2" painted on the rock.<br><br>A hollow voice says, "Plugh."

rule
at at_y2
litroom $room
open at_y2 plugh inside_building

verb go plugh
at at_y2
open inside_building plugh at_y2
untag dwarf wandering
hide dwarf
continue

#-------------------------------------

room jumble_of_rock You are in a jumble of rock, with cracks everywhere.
tags dark
prop name Jumble of Rock
down at_y2
up in_hall_of_mists

#-------------------------------------

room at_window_on_pit_1 You're at a low window overlooking a huge pit.
prop name Window on Pit
east at_y2

thing marks_1 marks in the dust
name marks in the dust
loc at_window_on_pit_1
desc Marks in the dust around the window would seem to indicate that someone has been here recently.
tags mass_noun

thing window_1 window across the pit
name window
loc at_window_on_pit_1
desc Directly across the pit from you and 25 feet away there is a similar window looking into a lighted room. A shadowy figure can be seen there peering back at you.

thing figure_1 shadowy figure
name shadowy figure
desc The shadowy figure seems to be trying to attract your attention.
verbs wave

verb wave figure_1
prompt wave at shadowy figure
say The shadowy figure waves back at you!

#-------------------------------------

room in_dirty_passage You are in a dirty passage.
tags dark
prop name Dirty Passage
east on_brink_of_pit
up low_n_s_passage
west in_dusty_rock_room

#-------------------------------------

room on_brink_of_pit You are on the brink of a small clean climbable pit.
prop name Brink of Pit
tags dark
west in_dirty_passage
down in_pit

#-------------------------------------

room in_pit You are in the bottom of a small pit with a little stream.
tags dark haswater no_dwarf stream
prop name In Pit
up on_brink_of_pit

verb go slits
say You don't fit through the tiny slits!

verb examine stream
at in_pit
say The stream enters and exits through tiny slits.
open in_pit slits inside_building #never happens

#-------------------------------------

room in_dusty_rock_room You are in a large room full of dusty rocks.
tags dark
prop name In Dusty Rock Room
east in_dirty_passage
down at_complex_junction

#------------------------------------

room alike_maze_1 You are in a maze of twisty little passages, all alike.
prop name Maze
up at_west_end_of_hall_of_mist
east alike_maze_2
south alike_maze_4
west alike_maze_11
#
down alike_maze_1
north alike_maze_1
#
tags dark

room alike_maze_2 { alike_maze_1.desc }
prop name Maze
east alike_maze_4
south alike_maze_3
west alike_maze_1
#
north alike_maze_2
up alike_maze_2
down alike_maze_2
#
tags dark

room alike_maze_3 { alike_maze_1.desc }
prop name Maze
east alike_maze_2
down dead_end_3
south alike_maze_6
north dead_end_13
#
west alike_maze_3
up alike_maze_3
#
tags dark

room alike_maze_4 { alike_maze_1.desc }
prop name Maze
west alike_maze_1
north alike_maze_2
east dead_end_1
south dead_end_2
up alike_maze_14
down alike_maze_14
tags dark

room alike_maze_5 { alike_maze_1.desc }
prop name Maze
east alike_maze_6
west alike_maze_7
#
north alike_maze_5
south alike_maze_5
up alike_maze_5
down alike_maze_5
#
tags dark

room alike_maze_6 { alike_maze_1.desc }
prop name Maze
east alike_maze_3
west alike_maze_5
down alike_maze_7
south alike_maze_8
#
north alike_maze_6
up alike_maze_6
#
tags dark

room dead_end_1 You are at a dead end.
prop name Dead End
west alike_maze_4
tags dark

room dead_end_2 You are at a dead end.
prop name Dead End
west alike_maze_4
tags dark

room dead_end_3 You are at a dead end.
prop name Dead End
up alike_maze_3
tags dark

room alike_maze_7 { alike_maze_1.desc }
prop name Maze
west alike_maze_5
up alike_maze_6
east alike_maze_8
south alike_maze_9
#
north alike_maze_7
down alike_maze_7
#
tags dark

room alike_maze_8 { alike_maze_1.desc }
prop name Maze
west alike_maze_6
east alike_maze_7
south alike_maze_8
up alike_maze_9
north alike_maze_10
down dead_end_12
tags dark

room alike_maze_9 { alike_maze_1.desc }
prop name Maze
west alike_maze_7
north alike_maze_8
south dead_end_4
#
east alike_maze_9
up alike_maze_9
down alike_maze_9
#
tags dark

room dead_end_4 You are at a dead end.
prop name Dead End
west alike_maze_9
tags dark

room alike_maze_10 { alike_maze_1.desc }
prop name Maze
west alike_maze_8
down dead_end_5
east at_brink_of_pit
#
north alike_maze_10
south alike_maze_10
up alike_maze_10
#
tags dark

room dead_end_5 You are at a dead end.
prop name Dead End
up alike_maze_10
tags dark

#-------------------------------------

room at_brink_of_pit You are on the brink of a thirty foot pit. The maze continues at this level.
prop name At Brink of Pit
tags dark
down in_bird_chamber
west alike_maze_10
south dead_end_6
north alike_maze_12
east alike_maze_13

thing column
loc at_brink_of_pit
desc There is a massive orange column down one wall. You could climb down here but you could not get back up.
verbs climb

verb climb column
goto in_bird_chamber

#--------------------------------------

room dead_end_6 You are at a dead end.
prop name Dead End
east at_brink_of_pit
tags dark

#-------------------------------------

room at_complex_junction You are at a complex junction. The air is damp here.
prop name Complex Junction
tags dark
up in_dusty_rock_room
west in_bedquilt
north in_shell_room
east in_anteroom

#-------------------------------------

room in_bedquilt You are in bedquilt. To explore at random select north, south, up, or down.
prop name Bedquilt
east at_complex_junction
west in_swiss_cheese_room
north at_junction_of_three
south in_slab_room
up in_dusty_rock_room
down in_anteroom

verb go south
at in_bedquilt
chance 80 100
say You have crawled around in some little holes and wound up back in the main passage.

verb go down
at in_bedquilt
chance 80 100
say You have crawled around in some little holes and wound up back in the main passage.

verb go up
at in_bedquilt
chance 80 100
say You have crawled around in some little holes and wound up back in the main passage.

verb go up
at in_bedquilt
chance 50 100
goto in_secret_n_s_canyon_1

verb go north
at in_bedquilt
chance 60 100
say You have crawled around in some little holes and wound up back in the main passage.

verb go north
at in_bedquilt
chance 75 100
goto in_large_low_room

#-------------------------------------

room in_swiss_cheese_room You are in a room whose walls resemble swiss cheese.
prop name Swiss Cheese Room
tags dark
west at_east_end_of_twopit_room
south in_tall_e_w_canyon
northeast in_bedquilt
northwest in_oriental_room
east in_soft_room

verb go south
at in_swiss_cheese_room
chance 80 100
say You have crawled around in some little holes and wound up back in the main passage.

verb go northwest
at in_swiss_cheese_room
chance 50 100
say You have crawled around in some little holes and wound up back in the main passage.

#-------------------------------------

room at_west_end_of_twopit_room You are at the west end of the twopit room. 
prop name West End of Twopit Room
tags dark
east at_east_end_of_twopit_room
west in_slab_room
down in_west_pit

thing hole_1 large hole
name large hole
loc at_west_end_of_twopit_room
desc There is a large hole in the wall above the pit at this end of the room.
verbs enter

verb enter hole_1
thingat huge_plant in_west_pit
goto in_narrow_corridor

verb enter hole_1
prompt enter large hole
say It is too far up for you to reach.

thing huge_plant_sticking_up beanstalk
name beanstalk
desc There is a huge beanstalk growing out of the west pit up to the hole.
verbs climb

verb climb huge_plant_sticking_up
goto in_narrow_corridor

thing large_plant_sticking_up beanstalk
name beanstalk
desc The top of a 12-foot-tall beanstalk is poking out of the west pit.
verbs climb

verb climb large_plant_sticking_up
thingat tall_plant in_west_pit
goto in_west_pit

verb climb large_plant_sticking_up
goto in_narrow_corridor

#------------------------------------

room in_west_pit You are at the bottom of the western pit in the twopit room.
prop name West Pit
tags dark no_dwarf
up at_west_end_of_twopit_room

thing hole_2 large hole
name large hole
loc in_west_pit
desc There is a large hole in the wall about 25 feet above you.
verbs enter

verb enter hole_2
goto at_west_end_of_twopit_room

thing tiny_plant
loc in_west_pit
desc There is a tiny plant in the pit, murmuring "Water, water, ..."
verbs climb

verb climb tiny_plant
say It's just a little plant.

thing tall_plant
desc There is a 12-foot-tall beanstalk stretching up out of the pit, bellowing "Water!! Water!!"
verbs climb

verb climb tall_plant
goto at_west_end_of_twopit_room

thing huge_plant
desc There is a gigantic beanstalk stretching all the way up to the hole.
verbs climb

verb climb huge_plant
goto in_narrow_corridor

#--------------------------------------

room at_east_end_of_twopit_room You are at the east end of twopit room.
prop name East End of Twopit room
tags dark
east in_swiss_cheese_room
west at_west_end_of_twopit_room
down in_east_pit

#--------------------------------------

room in_east_pit You are at the bottom of the eastern pit in the twopit room.
prop name East Pit
tags dark hasoil no_dwarf
up at_east_end_of_twopit_room

thing hole_3 large hole
name large hole
loc in_east_pit
desc The hole is in the wall above you.
verbs enter

verb enter hole_3
goto at_east_end_of_twopit_room

thing pool_of_oil
loc in_east_pit
desc There is a small pool of oil in one corner of the pit.

#--------------------------------------

room in_slab_room You are in a large low circular chamber whose floor is an immense slab fallen from the ceiling (slab room).
prop name Slab Room
south at_west_end_of_twopit_room
up in_secret_n_s_canyon_0
north bedquilt

#-------------------------------------

room in_secret_n_s_canyon_0 You are in a secret N/S canyon above a large room.
prop name Secret N/S Canyon
tags dark
down in_slab_room
south in_secret_canyon
north in_mirror_canyon

verb go south
at in_secret_n_s_canyon_0
write in_secret_canyon.canyon_from in_secret_n_s_canyon_0
continue

#-----------------------------------

room in_secret_n_s_canyon_1 You are in a secret N/S canyon above a sizeable passage.
prop name Secret N/S Canyon
tags dark
north at_junction_of_three
down in_bedquilt
south atop_stalactite

#----------------------------------

room at_junction_of_three You are in a secret canyon at a junction of three canyons.
prop name Junction of Three Secret Canyons
tags dark
southeast in_bedquilt
south in_secret_n_s_canyon_1
north at_window_on_pit_2

#----------------------------------

room in_large_low_room You are in a large low room.
prop name Large Low Room
tags dark
southwest in_sloping_corridor
southeast in_oriental_room
north dead_end_crawl

#----------------------------------

room dead_end_crawl This is a dead end crawl.
prop name Dead End Crawl
tags dark
south in_large_low_room

#----------------------------------

room in_secret_e_w_canyon You are in a secret canyon which here runs E/W.
prop name Secret E/W Canyon
tags dark
east in_hall_of_mt_king
west in_secret_canyon
down in_n_s_canyon

verb go west
at in_secret_e_w_canyon
write in_secret_canyon.canyon_from in_secret_e_w_canyon
continue

#------------------------------------

room in_n_s_canyon You are at a wide place in a very tight N/S canyon.
prop name N/S Canyon
tags dark
south canyon_dead_end
north in_tall_e_w_canyon

#------------------------------------

room canyon_dead_end The canyon here becomes too tight to go further south.
prop name Canyon Dead End
tags dark
north in_n_s_canyon

#------------------------------------

room in_tall_e_w_canyon You are in a tall E/W canyon.
prop name Tal E/W Canyon
tags dark
east in_n_s_canyon
west dead_end_8
north in_swiss_cheese_room

#------------------------------------

room atop_stalactite You are atop a large stalactite
prop name Atop a Stalactite
tags dark
north in_secret_n_s_canyon_1
down alike_maze_4

verb go down
at atop_stalactite
chance 40 100
goto alike_maze_6

verb go down
at atop_stalactite
chance 60 100
goto alike_maze_9

thing large_stalactite
loc atop_stalactite
tags quiet
desc The large stalactite extends from the roof and almost reaches the floor below. You could climb down it, and jump from it to the floor, but having done so you would be unable to reach it to climb back up.
verbs climb jump

verb climb large_stalactite
prompt climb down stalactite
chance 40 100
goto alike_maze_6

verb climb large_stalactite
chance 60 100
goto alike_maze_9

verb climb large_stalactite
goto alike_maze_4

verb jump large_stalactite
prompt jump down stalactite
chance 40 100
goto alike_maze_6

verb jump large_stalactite
chance 60 100
goto alike_maze_9

verb jump large_stalactite
goto alike_maze_4

#------------------------------------

room in_secret_canyon You are in a secret canyon.
prop name Secret Canyon
tags dark
east in_secret_e_w_canyon
north in_secret_n_s_canyon_0

verb go east
at in_secret_canyon
!eq in_secret_canyon.canyon_from in_secret_e_w_canyon
say The dragon looks rather nasty. You'd best not try to get by.

verb go north
at in_secret_canyon
!eq in_secret_canyon.canyon_from in_secret_n_s_canyon_0
say The dragon looks rather nasty. You'd best not try to get by.

thing dragon
loc in_secret_canyon
desc I wouldn't mess with it if I were you.

setverb attack dragon
!has dragon attacked

verb attack dragon
tag dragon attacked
say With what? Your bare hands.

setverb yes dragon
has dragon attacked

verb yes dragon
say Congratulations! You have just vanquished a dragon with your bare hands! (Unbelievable, isn't it?)
swap dragon dragon_corpse
write persian_rug.desc The finest persian rug.

setverb no dragon
has dragon attacked

verb no dragon
say I should think not.
untag dragon attacked

thing dragon_corpse dragon's corpse
name dragon's corpse
desc The body of a huge green dragon is lying off to one side.
verbs attack

verb attack dragon_corpse
say You've already done enough damage!

rule
has dragon reset
untag dragon reset
untag dragon attacked

rule
has dragon attacked
tag dragon reset

thing persian_rug
loc in_secret_canyon
desc The dragon is sprawled out on the persian rug!
tags portable treasure
prop deposit_take -14
prop deposit_drop 14

verb take persian_rug
visible dragon
say You'll need to get the dragon to move first.

# throw axe

setverb throw_at_dragon
carried $this
visible dragon

verb throw_at_dragon
say You'd probably be better off using you bare hands than that thing.

#-------------------------------------

room dead_end_8 The canyon runs into a mass of boulders -- dead end.
prop name Dead End
tags dark
south in_tall_e_w_canyon

room alike_maze_11 { alike_maze_1.desc }
prop name Maze
tags dark
north alike_maze_1
east dead_end_9
northeast dead_end_10
#
south alike_maze_11
up alike_maze_11
down alike_maze_11

room dead_end_9 You are at a dead end.
prop name Dead End
tags dark
west alike_maze_11

room dead_end_10 You are at a dead end.
prop name Dead End
tags dark
south alike_maze_3

room alike_maze_12 { alike_maze_1.desc }
prop name Maze
tags dark
south at_brink_of_pit
east alike_maze_13
west dead_end_11
#
north alike_maze_12
up alike_maze_12
down alike_maze_12

room alike_maze_13 { alike_maze_1.desc }
prop name Maze
tags dark
north at_brink_of_pit
west alike_maze_12
northwest dead_end_13
#
south alike_maze_13
east alike_maze_13
up alike_maze_13
down alike_maze_13

verb go northwest
!has pirate chest_found
at alike_maze_13
tag pirate chest_found
say You've found the pirate's treasure chest.
say
continue

room dead_end_11 You are at a dead end.
prop name Dead End
east alike_maze_12

room dead_end_12 You are at a dead end.
prop name Dead End
up alike_maze_8

room alike_maze_14 { alike_maze_1.desc }
prop name Maze
tags dark
up alike_maze_4
down alike_maze_4
#
north alike_maze_14
south alike_maze_14
east alike_maze_14
west alike_maze_14

room dead_end_13 You are at a dead end.
prop name Dead End
tags dark  no_dwarf
southeast alike_maze_13

thing treasure_chest
loc dead_end_13
tags portable treasure
desc It's the pirate's treasure chest, filled with riches of all kinds.
prop deposit_take -12
prop deposit_drop 12

verb take treasure_chest
tag pirate spotted
continue

#-------------------------------------

room in_narrow_corridor You are in a long, narrow corridor.
prop name Narrow Corridor
tags dark
west in_giant_room
down in_west_pit

verb jump hole
prompt jump through hole
say You fall and break your neck.
die

thing hole
loc in_narrow_corridor
desc At the eastern end of the corridor is a hole through which you can see a profusion of leaves.
verbs enter jump

verb enter hole
prompt climb down beanstalk
goto in_west_pit

verb examine hole
bring leaves
continue

thing leaves
desc The leaves appear to be attached to the beanstalk you climbed to get here.
verbs climb count
tags plural

verb climb leaves
prompt climb down beanstalk
goto in_west_pit

verb count leaves
say 69,105.

#------------------------------------

room at_steep_incline You are at the top of a steep incline above a large room.
prop name Steep Incline
tags dark
north in_cavern_with_waterfall
down in_large_low_room

#------------------------------------

room in_giant_room You are in the giant room.
prop name Giant Room
tags dark
south in_narrow_corridor
east at_recent_cave_in
north in_immense_n_s_passage

thing inscription
loc in_giant_room
desc On the west wall is scrawled the inscription "Fee fie foe foo \[sic\]."
verbs read

verb examine inscription
tag inscription read
continue

verb read inscription
say "Fee fie foe foo \[sic\]."
tag inscription read

thing nest_of_golden_eggs
loc in_giant_room
tags portable treasure
desc The nest is filled with beautiful golden eggs!
prop deposit_take -14
prop deposit_drop 14

#------------------------------------

setverb incant intransitive
has inscription read
at in_giant_room
!inscope nest_of_golden_eggs

verb incant
run clear
assign answer_room.return in_giant_room
write answer_room.desc Incant what? (3 char max)
goto answer_room

#-------------------------------------

room at_recent_cave_in The passage here is blocked by a recent cave-in.
prop name Recent Cave-In
tags dark
south in_giant_room

#-------------------------------------

room in_immense_n_s_passage You are at one end of an immense north/south passage.
prop name Immense N/S Passage
tags dark
south in_giant_room

thing rusty_door
loc in_immense_n_s_passage
desc It's just a big iron door.

setverb open rusty_door
!has rusty_door open

verb open rusty_door
!has rusty_door oiled
say The hinges are quite thoroughly rusted now and won't budge.

verb open rusty_door
say The door heaves open with a shower of rust.
tag rusty_door open
open in_immense_n_s_passage north in_cavern_with_waterfall

setverb close rusty_door
has rusty_door open

verb close rusty_door
say With all the effort it took to get the door open, I wouldn't suggest closing it again.

#-------------------------------------

room in_cavern_with_waterfall You are in a magnificent cavern with a sparkling waterfall.
prop name Cavern with Waterfall
tags dark haswater
south in_immense_n_s_passage
west at_steep_incline

thing rusty_door2 rusty door
name rusty door
loc in_cavern_with_waterfall
desc It's just a big iron door.
verbs close

verb close rusty_door2
prompt close rusty door
say With all the effort it took to get the door open, I wouldn't suggest closing it again.

thing waterfall
loc in_cavern_with_waterfall
desc Wouldn't want to go down in a barrel!
tags quiet

thing trident jeweled trident
loc in_cavern_with_waterfall
desc The trident is covered with fabulous jewels!
tags portable treasure
prop deposit_take -14
prop deposit_drop 14

#----------------------------------

room in_soft_room You are in the soft room.
prop name Soft Room
tags dark
west in_swiss_cheese_room

thing velvet_pillow
loc in_soft_room
tags portable
desc It's just a small velvet pillow.

#---------------------------------

room in_oriental_room This is the oriental room.
prop name Oriental Room
tags dark
west in_large_low_room
southeast in_swiss_cheese_room
north in_misty_cavern

thing ming_vase
loc in_oriental_room
desc It's a delicate, precious, ming vase!
tags portable treasure
prop deposit_take -14
prop deposit_drop 14

verb drop ming_vase
!here velvet_pillow
say The ming vase drops with a delicate crash.
hide ming_vase
put shards $room

verb drop ming_vase
say The vase is now resting, delicately, on a velvet pillow.
untag velvet_pillow portable
continue

verb take ming_vase
tag velvet_pillow portable
continue

thing shards
tags portable
desc They look to be the remains of what was once a beautiful vase. I guess some oaf must have dropped it.

#-------------------------------------

room in_misty_cavern You are following a wide path around the outer edge of a large cavern.
prop name Large Cavern
tags dark
south in_oriental_room
west in_alcove

#--------------------------------------

room in_alcove You are in an alcove.
prop name Alcove
tags dark
northwest in_misty_cavern
east in_plover_room

verb go east
at in_alcove
count held carried
gt $held 1 
say Something you're carrying won't fit through the tunnel with you. You'd best take inventory and drop something.

verb go east
at in_alcove
count held carried
eq $held 1
!carried egg_sized_emerald
say Something you're carrying won't fit through the tunnel with you. You'd best take inventory and drop something.

#--------------------------------------

room in_plover_room You're in a small chamber lit by an eerie green light.
prop name Plover Room
northeast in_dark_room
west in_alcove
dir plover at_y2

verb go west
at in_plover_room
count held carried
gt $held 1 
say Something you're carrying won't fit through the tunnel with you. You'd best take inventory and drop something.

verb go west
at in_plover_room
count held carried
eq $held 1
!carried egg_sized_emerald
say Something you're carrying won't fit through the tunnel with you. You'd best take inventory and drop something.

verb go plover
at in_plover_room
carried egg_sized_emerald
bring egg_sized_emerald
untag dwarf wandering
hide dwarf
continue

thing egg_sized_emerald
loc in_plover_room
tags portable treasure
desc This is an emerald the size of a plover's egg! - Plover's eggs, by the way, are quite large.
prop deposit_take -14
prop deposit_drop 14

#-------------------------------------

room in_dark_room You're in the dark-room.
prop name Dark Room
tags dark no_dwarf
south in_plover_room

thing stone_tablet
loc in_dark_room
desc The massive stone tablet imbedded in the wall reads: "Congratulations on bringing light into the dark-room!"

thing platinum_pyramid
loc in_dark_room
tags portable treasure
desc The platinum pyramid is 8 inches on a side!
prop deposit_take -14
prop deposit_drop 14

#-------------------------------------

room in_arched_hall You are in an arched hall.
tags dark
south in_shell_room
prop name Arched Hall

#-------------------------------------

room in_shell_room  You're in a large room carved out of sedimentary rock. The floor and walls are littered with bits of shells imbedded in the stone.
prop name Shell Room
up in_arched_hall
down in_ragged_corridor
south at_complex_junction

verb go south
at in_shell_room
carried giant_bivalve
say You can't fit this five-foot {giant_bivalve.name} through that little passage!

thing giant_bivalve giant {giant_bivalve.name}
loc in_shell_room
tags portable
prop name clam
desc A giant bivalve of some kind.
verbs attack

setverb open_clam
!eq $this giant_bivalve
visible giant_bivalve
held $this
prompt open {giant_bivalve.name} with {the $this}
display open {giant_bivalve.name}

verb open_clam
eq $this axe
run open_clam

verb open_clam
eq $this trident
run open_clam

proc open_clam
is giant_bivalve.name clam:The oyster creaks open, revealing nothing but the oyster inside. It promptly snaps shut again.
say A glistening pearl falls out of the clam and rolls away. Goodness, this must really be an oyster. (I never was very good at identifying bivalves.) Whatever it is, it has now snapped shut again.
write giant_bivalve.name oyster
put pearl in_a_cul_de_sac

verb open_clam
say {The $this} isn't strong enough to open the {giant_bivalve.name}.

verb attack giant_bivalve
say The shell is very strong and is impervious to attack.

thing pearl glistening pearl
tags portable treasure
desc It's incredibly large!
prop deposit_take -14
prop deposit_drop 14

#-------------------------------------

room in_ragged_corridor You are in a long sloping corridor with ragged sharp walls.
tags dark
up in_shell_room
down in_a_cul_de_sac
prop name Ragged Corridor

room in_a_cul_de_sac You're in a cul-de-sac about eight feet across.
tags dark
up in_ragged_corridor
prop name Cul-de-Sac

#------------------------------------

room in_anteroom You are in an anteroom.
prop name Anteroom
tags dark
up at_complex_junction
west in_bedquilt
east at_witts_end

thing sign
loc in_anteroom
desc  A sign in midair here says "Cave under construction beyond this point. Proceed at own risk.[Witt Construction Company]"
verbs read

verb read sign
say "Cave under construction beyond this point. Proceed at own risk.[Witt Construction Company]"

thing magazines Spelunker Today magazines
tags portable plural
loc in_anteroom
desc A few recent issues of "Spelunker Today" magazine.

verb take magazines
at at_witts_end
add score -1
continue

verb drop magazines
at at_witts_end
add score 1
say You really are at wit's end.
continue

#------------------------------------

room at_witts_end You are at Witt's End.
prop name Witt's End
tags dark
dir leave in_anteroom

verb go leave
chance 95 100
say You have crawled around in some little holes and wound up back in the main passage.

#-----------------------------------

room in_mirror_canyon You are in a north/south canyon about 25 feet across.
tags dark
prop name Mirror Canyon
south in_secret_n_s_canyon_0
north at_reservoir

thing suspended_mirror
loc in_mirror_canyon
desc Suspended from some unseen point far above you, an enormous two-sided mirror is hanging parallel to and midway between the canyon walls. The mirror is obviously provided for the use of the dwarves, who as you know, are extremely vain.
verbs attack

verb attack suspended_mirror
say  You can't reach it from here.

thing canyon_walls
loc in_mirror_canyon
desc The walls extend upward for well over 100 feet. A small window can be seen in either wall, some fifty feet up.

#-----------------------------------

room at_window_on_pit_2 You're at a low window overlooking a huge pit.
prop name Window on Pit
west at_junction_of_three
dir jump nowhere

verb go jump
at at_window_on_pit_2
say You jump and break your neck!
die

thing marks_2 marks in the dust
name marks in the dust
loc at_window_on_pit_2
desc Marks in the dust around the window would seem to indicate that someone has been here recently.
tags mass_noun

thing window_2 window across the pit
name window
loc at_window_on_pit_2
desc Directly across the pit from you and 25 feet away there is a similar window looking into a lighted room. A shadowy figure can be seen there peering back at you.

thing figure_2 shadowy figure
name shadowy figure
desc The shadowy figure seems to be trying to attract your attention.
verbs wave

verb wave figure_2
prompt wave at shadowy figure
say The shadowy figure waves back at you!

#------------------------------------

room at_reservoir You are at the edge of a large underground reservoir.
prop name Reservoir
tags dark haswater
south in_mirror_canyon

setverb swim intransitive
at at_reservoir

verb swim
say The water is icy cold, and you would soon freeze to death.

#-------------------------------------

room in_sloping_corridor You are in a long winding corridor sloping out of sight in both directions.
prop name Sloping Corridor
down in_large_low_room
up on_sw_side_of_chasm
tags dark

#-------------------------------------

room on_sw_side_of_chasm You are on one side of a large, deep chasm.
tags dark
prop name SW Side of Chasm
dir jump nowhere
southwest in_sloping_corridor

verb go jump
at on_sw_side_of_chasm
visible rickety_bridge
say I respectfully suggest you go across the bridge instead of jumping.

verb go jump
at on_sw_side_of_chasm
say You didn't make it.
die

thing rickety_bridge
loc on_sw_side_of_chasm
desc A rickety wooden bridge extends across the chasm, vanishing into the mist. A sign posted on the bridge reads "Stop! Pay troll!"
verbs cross

verb cross rickety_bridge
visible troll
say The troll refuses to let you cross.

verb cross rickety_bridge
!has troll dead
!has troll treasured
!visible troll
say The troll steps out from beneath the bridge and blocks your way.
bring troll

verb cross rickety_bridge
has bear following
hide bear
has troll dead
swap rickety_bridge wreckage
untag bear following
say Just as you reach the otherside, the bridge buckles beneath the weight of the bear,	which was still following you around. You scrabble desperately for support, but as the bridge collapses you stumble back and fall into the chasm.
die

verb cross rickety_bridge
at on_sw_side_of_chasm
!visible troll
put rickety_bridge on_ne_side_of_chasm
goto on_ne_side_of_chasm
untag troll treasured

verb cross rickety_bridge
at on_ne_side_of_chasm
!visible troll
put rickety_bridge on_sw_side_of_chasm
goto on_sw_side_of_chasm
untag troll treasured

thing troll burly troll
verbs attack talk_to
desc Trolls are close relatives with rocks and have skin as tough as that of a rhinoceros. This one stands by the bridge and insists you throw him a treasure before you may cross.

verb attack troll
say The troll laughs aloud at your pitiful attempts to injure him.

verb talk_to troll
say Trolls make poor conversation.

setverb throw_to_troll
carried $this
visible troll

verb throw_to_troll
!has $this treasure
say The troll deftly catches {the $this.display}, examines it carefully, and tosses it back, declaring, "Good workmanship, but it's not valuable enough."

verb throw_to_troll
say The troll catches your treasure and scurries away out of sight.
hide $this
hide troll
add score -5
tag troll treasured

thing wreckage wreckage of bridge
desc The wreckage of the troll bridge (and a dead bear)	can be seen at the bottom of the chasm.

#-------------------------------------

room on_ne_side_of_chasm You are on the far side of the chasm.
prop name NE Side of Chasm
northeast in_corridor
dir jump nowhere
tags  no_dwarf

verb go jump
at on_ne_side_of_chasm
visible rickety_bridge
say I respectfully suggest you go across the bridge instead of jumping.

verb go jump
at on_ne_side_of_chasm
say You didn't make it.
die

#-----------------------------------

room in_corridor You're in a long east/west corridor. A faint rumbling noise can be heard in the distance.
tags dark no_dwarf
west on_ne_side_of_chasm
east at_fork_in_path
prop name Corridor

#------------------------------------

room at_fork_in_path The path forks here. A dull rumbling seems to get louder to the northeast.
prop name Fork in Path
tags dark no_dwarf
west in_corridor
northeast at_junction_with_warm_walls
southeast in_limestone_passage

#-----------------------------------

room at_junction_with_warm_walls The walls are quite warm here. From the north can be heard a steady roar.
prop name Junction With Warm Walls
tags dark no_dwarf
south at_fork_in_path
north at_breath_taking_view
east in_chamber_of_boulders

#------------------------------------

room at_breath_taking_view You are on the edge of a breath-taking view.
prop name Breath Taking View
verbs volcano
south at_junction_with_warm_walls
dir jump nowhere

verb go jump
at at_breath_taking_view
say Don't be ridiculous!

setverb jagged_roof intransitive
at at_breath_taking_view
has at_breath_taking_view volcanoed

setverb deep_gorge intransitive
at at_breath_taking_view
has at_breath_taking_view roofed

setverb geyser intransitive
at at_breath_taking_view
has at_breath_taking_view gorged

verb volcano
say Far below you is an active volcano, from which great gouts of molten lava come surging out, cascading back down into the depths. The glowing rock fills the farthest reaches of the cavern with a blood-red glare, giving everything an eerie, macabre appearance. The air is filled with flickering sparks of ash and a heavy smell of brimstone. The walls are hot to the touch, and the thundering of the volcano drowns out all other sounds.
tag at_breath_taking_view volcanoed

verb jagged_roof
say Embedded in the jagged roof far overhead are myriad twisted formations composed of pure white alabaster, which scatter the murky light into sinister apparitions upon the walls.
tag at_breath_taking_view roofed

verb deep_gorge
say To one side is a deep gorge, filled with a bizarre chaos of tortured rock which seems to have been crafted by the devil himself. An immense river of fire crashes out from the depths of the volcano, burns its way through the gorge, and plummets into a bottomless pit far off to your left.
tag at_breath_taking_view gorged

verb geyser
say To the right, an immense geyser of blistering steam erupts continuously from a barren island in the center of a sulfurous lake, which bubbles ominously. The far right wall is aflame with an incandescence of its own, which lends an additional infernal splendor to the already hellish scene.

#-------------------------------------

room in_chamber_of_boulders You are in a small chamber filled with large boulders.
prop name Chamber of Boulders
west at_junction_with_warm_walls
tags dark no_dwarf

thing rare_spices
loc in_chamber_of_boulders
tags portable treasure
desc A selection of rare spices. They smell wonderfully exotic.
prop deposit_take -14
prop deposit_drop 14

#------------------------------------

room in_limestone_passage A gently sloping north/south passage lined with oddly shaped limestone formations.
prop name Limestone Passage
tags dark no_dwarf
north at_fork_in_path
south in_front_of_barren_room

#-----------------------------------

room in_front_of_barren_room You are standing at the entrance to a large, barren room.
prop name In Front of Barren Room
tags dark no_dwarf
west in_limestone_passage
east in_barren_room

thing sign2 sign
name sign
loc in_front_of_barren_room
desc Posted above the entrance it reads: "Caution! Bear in room!"
verbs read

verb read sign2
prompt read sign
say "Caution! Bear in room!"

#-----------------------------------

room in_barren_room You are inside a barren room.
prop name Barren Room
tags dark no_dwarf
west in_front_of_barren_room

thing bear ferocious cave bear
loc in_barren_room
desc The bear is extremely large, and seems quite ferocious! The bear is eyeing you from the far end of the room!

setverb give_to_bear
carried $this
visible bear

verb give_to_bear food
prompt feed food to bear
hide food
tag bear friendly
say The bear eagerly wolfs down your food, after which he seems to calm down considerably and even becomes rather friendly.
write bear.desc The bear is extremely large, but appears to be friendly. The bear is sitting placidly in one corner.
write bear.display friendly cave bear

verb give_to_bear
prompt give {$this} to bear
has bear friendly
say The bear doesn't seem interested in your offer.

verb give_to_bear
say Uh-oh --- your offer only makes the bear angrier.

setverb follow bear
has bear friendly
has golden_chain portable
!has bear following

verb follow bear
prompt follow me
display follow me
tag bear following
say Ok, the bear's now following you around.
write bear.desc The bear is extremely large, but appears to be friendly. The bear is following close behind you.

setverb release bear
has bear following

verb release bear
visible troll
hide troll
tag troll dead
say The bear lumbers toward the troll, who lets out a startled shriek and scurries away. The bear soon gives up the pursuit and wanders back.
say
continue

verb release bear
untag bear following
write bear.desc The bear is extremely large, but appears to be friendly. The bear is wandering about nearby.
say The bear wanders away from you.

thing golden_chain
loc in_barren_room
tags treasure
desc The chain has thick links of solid gold. The bear is held back by the locked gold chain.
prop deposit_take -14
prop deposit_drop 14

setverb unlock golden_chain
!has golden_chain portable

verb unlock golden_chain
!has bear friendly
say There is no way to get past the bear to unlock the chain, which is probably just as well.

verb unlock golden_chain
say You unlock the chain, and set the tame bear free.
tag golden_chain portable
write golden_chain.desc The chain has thick links of solid gold.

rule
!visible bear
has bear following
bring bear
say
say The bear lumbers along behind you.

rule
at at_breath_taking_view
visible bear
say
say The bear roars with delight.

#-------------------------------------

room different_maze_1 You are in a maze of twisty little passages, all different.
prop name Maze
south different_maze_3
southwest different_maze_4
northeast different_maze_5
southeast different_maze_6
up different_maze_7
northwest different_maze_8
east different_maze_9
west different_maze_10
north different_maze_11
down at_west_end_of_long_hall
tags dark

room different_maze_2 You are in a little maze of twisting passages, all different.
prop name Maze
southwest different_maze_3
north different_maze_4
east different_maze_5
northwest different_maze_6
southeast different_maze_7
northeast different_maze_8
west different_maze_9
down different_maze_10
up different_maze_11
south dead_end_14
tags dark

room different_maze_3 You are in a maze of twisting little passages, all different.
prop name Maze
west different_maze_1
southeast different_maze_4
northwest different_maze_5
southwest different_maze_6
northeast different_maze_7
up different_maze_8
down different_maze_9
north different_maze_10
south different_maze_11
east different_maze_2
tags dark

room different_maze_4 You are in a little maze of twisty passages, all different.
prop name Maze
northwest different_maze_1
up different_maze_3
north different_maze_5
south different_maze_6
west different_maze_7
southwest different_maze_8
northeast different_maze_9
east different_maze_10
down different_maze_11
southeast different_maze_2
tags dark

room different_maze_5 You are in a twisting maze of little passages, all different.
prop name Maze
up different_maze_1
down different_maze_3
west different_maze_4
northeast different_maze_6
southwest different_maze_7
east different_maze_8
north different_maze_9
northwest different_maze_10
southeast different_maze_11
south different_maze_2
tags dark

room different_maze_6 You are in a twisting little maze of passages, all different.
prop name Maze
northeast different_maze_1
north different_maze_3
northwest different_maze_4
southeast different_maze_5
east different_maze_7
down different_maze_8
south different_maze_9
up different_maze_10
west different_maze_11
southwest different_maze_2
tags dark

room different_maze_7 You are in a twisty little maze of passages, all different.
prop name Maze
north different_maze_1
southeast different_maze_3
down different_maze_4
south different_maze_5
east different_maze_6
west different_maze_8
southwest different_maze_9
northeast different_maze_10
northwest different_maze_11
up different_maze_2
tags dark

room different_maze_8 You are in a twisty maze of little passages, all different.
prop name Maze
east different_maze_1
west different_maze_3
up different_maze_4
southwest different_maze_5
down different_maze_6
south different_maze_7
northwest different_maze_9
southeast different_maze_10
northeast different_maze_11
north different_maze_2
tags dark

room different_maze_9 You are in a little twisty maze of passages, all different.
prop name Maze
southeast different_maze_1
northeast different_maze_3
south different_maze_4
down different_maze_5
up different_maze_6
northwest different_maze_7
north different_maze_8
southwest different_maze_10
east different_maze_11
west different_maze_2
tags dark

room different_maze_10 You are in a maze of little twisting passages, all different.
prop name Maze
down different_maze_1
east different_maze_3
northeast different_maze_4
up different_maze_5
west different_maze_6
north different_maze_7
south different_maze_8
southeast different_maze_9
southwest different_maze_11
northwest different_maze_2
tags dark

room different_maze_11 You are in a maze of little twisty passages, all different.
prop name Maze
southwest different_maze_1
northwest different_maze_3
east different_maze_4
west different_maze_5
north different_maze_6
down different_maze_7
southeast different_maze_8
up different_maze_9
south different_maze_10
northeast different_maze_2
tags dark

room dead_end_14 You have reached a dead end.
tags dark no_dwarf
north different_maze_2

thing vending_machine
loc dead_end_14
desc The instructions on the vending machine read,	"Insert coins to receive fresh batteries."

setverb put_in_machine
carried $this
visible vending_machine

verb put_in_machine
eq $this rare_coins
say Soon after you insert the coins in the coin slot, the vending machine makes a grinding sound, and a set of fresh batteries falls at your feet.
bring fresh_batteries
hide rare_coins
untag fresh_batteries in_machine

verb put_in_machine
say The machine seems to be designed to take coins.

thing fresh_batteries
desc They look like ordinary batteries. (A sepulchral voice says "Still going!")
tags portable plural in_machine

setverb replace fresh_batteries
prompt replace batteries
visible lantern
carried fresh_batteries

verb replace fresh_batteries
hide fresh_batteries
bring wornout_batteries
say You replace the batteries.
tag lantern batteried
write lantern.battery 2500

thing wornout_batteries worn-out batteries
desc They look like ordinary (worn-out) batteries.
tags portable plural

setverb replace wornout_batteries
prompt replace batteries
visible lantern
carried wornout_batteries

verb replace wornout_batteries
say Those batteries are dead; they won't do any good at all.

#----------------------------------
# dealing with treasures

verb take
has $this treasure
!has $this found
add found 1
tag $this found
add score 2
continue

verb take
has $this treasure
write taken Taken!
continue

verb drop
has $this treasure
at inside_building
write dropped Safely deposited.
continue

rule
write taken Taken.
write dropped Dropped.

verb take
has $this treasure
at inside_building
add score $this.deposit_take
continue

verb drop
has $this treasure
at inside_building
add score $this.deposit_drop
continue

verb take
has $this treasure
add score 5
continue

verb drop 
has $this treasure
add score -5
continue

#----------------------------------
# the endgame

rule
!has inside_building caves_closed
eq $found 15
add score 25
say
say A sepulchral voice reverberating through the cave says, "Cave closing soon. All adventurers exit immediately through main office."
tag inside_building caves_closed

rule
has inside_building caves_closed
lt $timer 26
add timer 1
eq $timer 25
add score 10
say
say The sepulchral voice intones, "The cave is now closed." As the echoes fade there is a blinding flash of light	(and a small puff of orange smoke)...
say As your eyes refocus, you look around...
goto at_ne_end
run drop_all

proc drop_all
all carried
hide $this

room at_ne_end You are at the northeast end of an immense room.
tags endgame
prop name NE End of Repository
southwest at_sw_end
verbs look_around

setverb blast intransitive
at at_ne_end
has at_sw_end visited

verb look_around
at at_ne_end
say You are at the northeast end of an immense room, even larger than the giant room. It appears to be a repository for the "Adventure" program. Massive torches far overhead bathe the room with smoky yellow light. Scattered about you can be seen a pile of bottles (all of them empty), a nursery of young beanstalks murmuring quietly, a bed of oysters, a bundle of black rods with rusty stars on their ends, and a collection of brass lanterns. Off to one side a great many dwarves are sleeping on the floor, snoring loudly. A sign nearby reads: "Do not disturb the dwarves!"

thing enormous_mirror
loc at_ne_end
desc The mirror is hanging against one wall, and stretches to the other end of the room, where various other sundry objects can be glimpsed dimly in the distance.
verbs attack

verb attack enormous_mirror
say You strike the mirror a resounding blow, whereupon it shatters into a myriad tiny fragments.
say
run wake_dwarves

thing game_materials
loc at_ne_end
desc You've seen everything in here already, albeit in somewhat different contexts.
verbs take
tags plural

verb take game_materials
say Realizing that by removing the loot here you'd be ruining the game for future players, you leave the "Adventure" materials where they are.

verb go southwest
at at_ne_end
put game_materials at_sw_end
tag at_sw_end visited
continue

verb go northeast
at at_sw_end
put game_materials at_ne_end
continue

thing sleeping_dwarves
loc at_ne_end
tags plural
desc I wouldn't bother the dwarves if I were you.
verbs take wake attack

verb take sleeping_dwarves
say What, all of them?

verb wake sleeping_dwarves
say You prod the nearest dwarf, who wakes up grumpily, take one look at you, curses, and grabs for his axe.
say
run wake_dwarves

verb attack sleeping_dwarves
run wake_dwarves

proc wake_dwarves
say The resulting ruckus has awakened the dwarves. There are now dozens of threatening little dwarves in the room with you! Most of them throw knives at you! All of them get you!
die

room at_sw_end You are at the southeast end of the repository.
tags endgame
prop name SW End of Repository
northeast at_ne_end
verbs look_around blast

verb look_around
at at_sw_end
say You are at the southeast end of the repository. To one side is a pit full of fierce green snakes. On the other side is a row of small wicker cages, each of which contains a little sulking bird. In one corner is a bundle of black rods with rusty marks on their ends. A large number of velvet pillows are scattered about on the floor. A vast mirror stretches off to the northeast.	At your feet is a large steel grate, next to which is a sign which reads, "TREASURE VAULT. Keys in main office."

thing steel_grate2 steel grate
name steel grate
loc at_sw_end
desc It just looks like an ordinary (closed and locked) steel grate.
verbs unlock

verb unlock steel_grate2
prompt unlock steel grate
say You don't have the key.

thing black_mark_rod
loc at_sw_end
desc It's a three foot black rod with a rusty mark on an end.
tags portable
verbs wave

verb wave black_mark_rod
say Nothing happens.

verb blast
at at_sw_end
thingat black_mark_rod at_ne_end
add score 35
say There is a loud explosion, and a twenty-foot hole appears in the far wall, burying the dwarves in the rubble. You march through the hole and find yourself in the main office, where a cheering band of friendly elves carry the conquering adventurer off into the sunset.
die Victory is yours.

verb blast
at at_ne_end
thingat black_mark_rod at_sw_end
add score 20
say There is a loud explosion, and a twenty-foot hole appears in the far wall, burying the snakes in the rubble. A river of molten lava pours in through the hole, destroying everything in its path, including you!
die

verb blast
say There is a loud explosion, and you are suddenly splashed across the walls of the room.
die

#-------------------------------------

# need to tidy this up

thing dwarf threatening dwarf
desc It's probably not a good idea to get too close. Suffice it to say the little guy's pretty aggressive.
verbs attack

verb attack dwarf
held axe
chance 66 100
add dwarf_count 1
hide dwarf
untag dwarf wandering
say You killed a little dwarf! The body vanishes in a cloud of greasy black smoke.
tag dwarf pause

verb attack dwarf
held axe
bring axe
say Missed! The little dwarf dodges out of the way of the axe.

verb attack dwarf
say You boot the dwarf across the room. He curses, then gets up and brushes himself off. Now he's madder than ever.

# dwarf attacks
rule
untag dwarf attacking
visible dwarf
chance 75 100
tag dwarf attacking

rule
visible dwarf
!has dwarf attacking
chance 33 100
say
say Tiring of this, the dwarf slips away.
hide dwarf
untag dwarf wandering
tag dwarf pause

rule
visible dwarf
has dwarf attacking
has axe dwarven
untag axe dwarven
bring axe
hide dwarf
untag dwarf attacking
untag dwarf wandering
say
say The dwarf throws a nasty little axe at you, misses. curses, and runs away.
tag dwarf pause

rule
visible dwarf
has dwarf attacking
say
untag dwarf attacking
chance 9 100: The dwarf throws a nasty little knife at you, but misses.
say The dwarf throws a nasty little knife at you, and hits!
die

# dwarf follows
rule
has dwarf wandering
litroom $room
!visible dwarf
!visible troll
!visible dragon
!visible bear
!visible pirate
chance 96 100
bring dwarf
say
say The dwarf stalks after you.

# or not
rule
has dwarf wandering
litroom $room
!visible dwarf
hide dwarf
untag dwarf wandering
tag dwarf pause

# dwarf appears
rule
!has dwarf pause
lt $dwarf_count 5
!has dwarf wandering
has $room dark
!has $room no_dwarf
litroom $room
!inscope bear
!inscope troll
!inscope pirate
chance 5 100
say
say A threatening little dwarf comes out of the shadows.
bring dwarf
tag dwarf wandering

rule
untag dwarf pause

thing axe dwarvish axe
desc It's just a little axe.
tags portable dwarven

#---------------------------------

thing pirate

rule
chance 3 100
run count_treasures
eq $ts 0
!has pirate spotted
has $room dark
!has $room no_dwarf
litroom $room
!visible dwarf
!visible dragon
!visible troll
!visible bear
say
tag pirate spotted
say There are feint rustling noises from the darkness behind you. As you turn toward them, you spot a bearded pirate. He is carrying a large chest.
say
say "Shiver me timbers!" he cries, "I've been spotted! I'd best hie meself off to the maze to hide me chest!"
say
say With that, he vanishes into the gloom.

rule
chance 3 100
run count_treasures
gt $ts 0
!has pirate stolen
has $room dark
!has $room no_dwarf
litroom $room
!visible dwarf
!visible dragon
!visible troll
!visible bear
tag pirate stolen
tag pirate spotted
say
say Out from the shadows behind you pounces a bearded pirate! "Har, har" he chortles. "I'll just take all this booty and hide it away with me chest deep in the maze!" He snatches your treasure and vanishes into the gloom.
run move_carried
all inscope
has $this treasure
put $this dead_end_13

proc move_carried
all carried
has $this treasure
put $this dead_end_13
add score -5

proc count_treasures
assign ts 0
all inscope
has $this treasure
add ts 1

#-------------------------------------
# change status line if dark
#-------------------------------------

rule
status { $room.name } | Score { $score } / { $maxscore }
taghere dark
status It's dark | Score { $score } / { $maxscore }
litroom $room
status { $room.name } | Score { $score } / { $maxscore }

#------------------------------------

rule
say

room info Notice board.
prop name Notice Board
dir return inside_building
verbs about credits parser_test

verb about
say Based on the original by Will Crowther and Don Woods.

verb credits
say Made using Gruescript by Robin Johnson.

verb cheats
say Switching off the dwarves and the pirate.

verb parser_test
run clear
assign answer_room.return info
write answer_room.desc Parser Test (3 char max)
goto answer_room

#-- THE ANSWER ROOM

room answer_room Type in your answer (10 char max)
prop name The Typing Room
verbs a b c d e f g h i j k l m n o p q r s t u v w x y z spc enter cancel restart

verb enter
eq answer_room.return info
say Entered {answer_room.1}{answer_room.2}{answer_room.3}
say
goto info

verb enter
eq answer_room.return in_giant_room
eq $fthing 3
eq answer_room.length 3
eq answer_room.1 f
eq answer_room.2 o
eq answer_room.3 o
say FOO
say
assign fthing 0
goto in_giant_room
say A large nest full of golden eggs suddenly appears out of nowhere!
say
bring nest_of_golden_eggs

verb enter
eq answer_room.return in_giant_room
eq $fthing 2
eq answer_room.length 3
eq answer_room.1 f
eq answer_room.2 o
eq answer_room.3 e
say FOE
say
assign fthing 3
goto in_giant_room

verb enter
eq answer_room.return in_giant_room
eq $fthing 1
eq answer_room.length 3
eq answer_room.1 f
eq answer_room.2 i
eq answer_room.3 e
say FIE
say
assign fthing 2
goto in_giant_room

verb enter
eq answer_room.return in_giant_room
eq $fthing 0
eq answer_room.length 3
eq answer_room.1 f
eq answer_room.2 e
eq answer_room.3 e
say FEE
say
assign fthing 1
goto in_giant_room

verb enter
eq answer_room.return in_giant_room
say Get it right, dummy!
say
assign fthing 0
goto in_giant_room

verb cancel
run clear
goto answer_room.return

verb restart
run clear
say {answer_room.desc}

proc clear
assign answer_room.length 0
assign answer_room.1 &nbsp;
assign answer_room.2 &nbsp;
assign answer_room.3 &nbsp;

rule
at answer_room
say > {answer_room.1}{answer_room.2}{answer_room.3}

proc string
lt answer_room.length 4
add answer_room.length 1
assign pos answer_room.length

verb a
run string
assign answer_room.$pos a

verb b
run string
assign answer_room.$pos b

verb c
run string
assign answer_room.$pos c

verb d
run string
assign answer_room.$pos d

verb e
run string
assign answer_room.$pos e

verb f
run string
assign answer_room.$pos f

verb g
run string
assign answer_room.$pos g

verb h
run string
assign answer_room.$pos h

verb i
run string
assign answer_room.$pos i

verb j
run string
assign answer_room.$pos j

verb k
run string
assign answer_room.$pos k

verb l
run string
assign answer_room.$pos l

verb m
run string
assign answer_room.$pos m

verb n
run string
assign answer_room.$pos n

verb o
run string
assign answer_room.$pos o

verb p
run string
assign answer_room.$pos p

verb q
run string
assign answer_room.$pos q

verb r
run string
assign answer_room.$pos r

verb s
run string
assign answer_room.$pos s

verb t
run string
assign answer_room.$pos t

verb u
run string
assign answer_room.$pos u

verb v
run string
assign answer_room.$pos v

verb w
run string
assign answer_room.$pos w

verb x
run string
assign answer_room.$pos x

verb y
run string
assign answer_room.$pos y

verb z
run string
assign answer_room.$pos z

verb spc
run string
assign answer_room.$pos _